cmake_minimum_required(VERSION 3.0.2)
project(pnkx_local_planner VERSION 1.0.0 LANGUAGES CXX)

if(DEFINED CATKIN_DEVEL_PREFIX OR DEFINED CATKIN_TOPLEVEL)
  set(BUILDING_WITH_CATKIN TRUE)
  message(STATUS "Building pnkx_local_planner with Catkin")

else()
  set(BUILDING_WITH_CATKIN FALSE)
  message(STATUS "Building pnkx_local_planner with Standalone CMake")
endif()

# C++ Standard - must be set before find_package
set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

# Find dependencies
find_package(Boost REQUIRED COMPONENTS system)

if (NOT BUILDING_WITH_CATKIN)

  # Enable Position Independent Code
  set(CMAKE_POSITION_INDEPENDENT_CODE ON)

  # Cấu hình RPATH để tránh cycle trong runtime search path
  set(CMAKE_BUILD_RPATH_USE_ORIGIN TRUE)
  set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  set(CMAKE_BUILD_RPATH "${CMAKE_BINARY_DIR}")

  set(PACKAGES_DIR
    robot_geometry_msgs
    robot_nav_msgs
    robot_std_msgs
    robot_visualization_msgs
    robot_nav_2d_msgs
    robot_nav_2d_utils
    robot_nav_core2
    mkt_msgs
    score_algorithm
    robot_costmap_2d
    tf3
    robot_tf3_geometry_msgs
    data_convert
    robot_cpp
    angles
  )

  find_library(TF3_LIBRARY NAMES tf3 PATHS /usr/lib /usr/local/lib /usr/lib/x86_64-linux-gnu)

else()

# ========================================================
# Catkin specific configuration
# ========================================================
  find_package(catkin REQUIRED COMPONENTS
    robot_geometry_msgs
    robot_nav_msgs
    robot_std_msgs
    robot_visualization_msgs
    robot_nav_2d_msgs
    robot_nav_2d_utils
    robot_nav_core2
    mkt_msgs
    score_algorithm
    robot_costmap_2d
    robot_tf3_geometry_msgs
    data_convert
    robot_cpp
    angles
  )

  find_library(TF3_LIBRARY NAMES tf3 PATHS /usr/lib /usr/local/lib /usr/lib/x86_64-linux-gnu)
  find_package(Boost REQUIRED COMPONENTS system)
  
  catkin_package(
    INCLUDE_DIRS include
    LIBRARIES ${PROJECT_NAME} ${PROJECT_NAME}_utils
    CATKIN_DEPENDS robot_geometry_msgs robot_nav_msgs robot_std_msgs robot_visualization_msgs robot_nav_2d_msgs robot_nav_2d_utils robot_nav_core2 mkt_msgs score_algorithm robot_costmap_2d robot_tf3_geometry_msgs data_convert robot_cpp angles
    DEPENDS Boost
  )

  include_directories(
    include
    ${catkin_INCLUDE_DIRS}
    ${Boost_INCLUDE_DIRS}
    ${TF3_INCLUDE_DIR}
  )
endif()

# ========================================================
# Libraries
# ========================================================
# Tạo thư viện utils trước
add_library(${PROJECT_NAME}_utils SHARED
  src/transforms.cpp
)

# Tạo thư viện chính
add_library(${PROJECT_NAME} SHARED
  src/pnkx_local_planner.cpp
  src/pnkx_go_straight_local_planner.cpp
  src/pnkx_rotate_local_planner.cpp
  src/pnkx_docking_local_planner.cpp
)

if(BUILDING_WITH_CATKIN)
  add_dependencies(${PROJECT_NAME}_utils ${${PROJECT_NAME}_EXPORTED_TARGETS} ${catkin_EXPORTED_TARGETS})
  add_dependencies(${PROJECT_NAME} ${${PROJECT_NAME}_EXPORTED_TARGETS} ${catkin_EXPORTED_TARGETS})

  target_include_directories(${PROJECT_NAME}_utils
    PUBLIC
      $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
      $<INSTALL_INTERFACE:include>
  )

  target_include_directories(${PROJECT_NAME}
    PUBLIC
      $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
      $<INSTALL_INTERFACE:include>
  )

  target_link_libraries(${PROJECT_NAME}_utils
    PUBLIC ${catkin_LIBRARIES}
    PRIVATE Boost::system
    ${TF3_LIBRARY}
  )

  target_link_libraries(${PROJECT_NAME}
    PUBLIC ${PROJECT_NAME}_utils
    PUBLIC ${catkin_LIBRARIES}
    PRIVATE Boost::system
    ${TF3_LIBRARY}
  )

else()

  target_include_directories(${PROJECT_NAME}_utils
    PUBLIC
      $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
      $<INSTALL_INTERFACE:include>
  )

  target_include_directories(${PROJECT_NAME}
    PUBLIC
      $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
      $<INSTALL_INTERFACE:include>
  )

  target_link_libraries(${PROJECT_NAME}_utils
    PUBLIC
      ${PACKAGES_DIR}
    PRIVATE
      Boost::system
  )

  target_link_libraries(${PROJECT_NAME}
    PUBLIC ${PROJECT_NAME}_utils
    PUBLIC
      ${PACKAGES_DIR}
    PRIVATE
      Boost::system
      ${TF3_LIBRARY}
  )

  set_target_properties(${PROJECT_NAME}_utils PROPERTIES
    LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}
    BUILD_RPATH "${CMAKE_BINARY_DIR}"
    INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib"
  )

  set_target_properties(${PROJECT_NAME} PROPERTIES
    LIBRARY_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}
    BUILD_RPATH "${CMAKE_BINARY_DIR}"
    INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/lib"
  )

endif()

# ========================================================
# Install
# ========================================================
if(BUILDING_WITH_CATKIN)
  ## Mark libraries for installation
  ## See http://docs.ros.org/melodic/api/catkin/html/howto/format1/building_libraries.html
  install(TARGETS ${PROJECT_NAME} ${PROJECT_NAME}_utils
    ARCHIVE DESTINATION ${CATKIN_PACKAGE_LIB_DESTINATION}
    LIBRARY DESTINATION ${CATKIN_PACKAGE_LIB_DESTINATION}
    RUNTIME DESTINATION ${CATKIN_GLOBAL_BIN_DESTINATION}
  )

  ## Mark cpp header files for installation
  install(DIRECTORY include/${PROJECT_NAME}/
    DESTINATION ${CATKIN_PACKAGE_INCLUDE_DESTINATION}
    FILES_MATCHING PATTERN "*.h"
    PATTERN ".svn" EXCLUDE
  )

  ## Install plugins.xml if it exists
  if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/plugins.xml)
    install(FILES plugins.xml
      DESTINATION ${CATKIN_PACKAGE_SHARE_DESTINATION}
    )
  endif()

else()

  install(TARGETS ${PROJECT_NAME} ${PROJECT_NAME}_utils
    EXPORT ${PROJECT_NAME}-targets
    ARCHIVE DESTINATION lib
    LIBRARY DESTINATION lib
    RUNTIME DESTINATION bin
  )

  # Export targets
  install(EXPORT ${PROJECT_NAME}-targets
    FILE ${PROJECT_NAME}-targets.cmake
    NAMESPACE ${PROJECT_NAME}::
    DESTINATION lib/cmake/${PROJECT_NAME}
  )

  ## Mark cpp header files for installation
  install(DIRECTORY include/${PROJECT_NAME}/
    DESTINATION include
    FILES_MATCHING PATTERN "*.h"
    PATTERN ".svn" EXCLUDE
  )

  ## Install plugins.xml if it exists
  if(EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/plugins.xml)
    install(FILES plugins.xml
      DESTINATION share/${PROJECT_NAME}
    )
  endif()

  # Print configuration info
  message(STATUS "=================================")
  message(STATUS "Project: ${PROJECT_NAME}")
  message(STATUS "Version: ${PROJECT_VERSION}")
  message(STATUS "C++ Standard: ${CMAKE_CXX_STANDARD}")
  message(STATUS "Libraries: ${PROJECT_NAME}, ${PROJECT_NAME}_utils")
  message(STATUS "Dependencies: robot_geometry_msgs, robot_nav_msgs, robot_std_msgs, robot_visualization_msgs, robot_nav_2d_msgs, robot_nav_2d_utils, robot_nav_core2, mkt_msgs, score_algorithm, robot_costmap_2d, tf3, robot_tf3_geometry_msgs, data_convert, robot_cpp, angles, Boost")
  message(STATUS "=================================")
endif()
