82 lines
3.0 KiB
CMake
82 lines
3.0 KiB
CMake
cmake_minimum_required(VERSION 3.10)
|
|
project(robot_geometry_msgs)
|
|
|
|
set(CMAKE_CXX_STANDARD 17)
|
|
set(CMAKE_CXX_STANDARD_REQUIRED ON)
|
|
|
|
# ========================================================
|
|
# Dual-mode CMakeLists.txt: Supports both Catkin and Standalone CMake
|
|
# ========================================================
|
|
|
|
# Detect if building with Catkin
|
|
if(DEFINED CATKIN_DEVEL_PREFIX OR DEFINED CATKIN_TOPLEVEL)
|
|
set(BUILDING_WITH_CATKIN TRUE)
|
|
message(STATUS "Building robot_geometry_msgs with Catkin")
|
|
else()
|
|
set(BUILDING_WITH_CATKIN FALSE)
|
|
message(STATUS "Building robot_geometry_msgs with Standalone CMake")
|
|
endif()
|
|
|
|
# ========================================================
|
|
# Catkin specific configuration
|
|
# ========================================================
|
|
|
|
if(BUILDING_WITH_CATKIN)
|
|
find_package(catkin REQUIRED COMPONENTS robot_std_msgs utils robot_time)
|
|
## The catkin_package macro generates cmake config files for your package
|
|
## Note: Dependencies (robot_std_msgs, utils, etc.) are not Catkin packages,
|
|
## they are built as CMake targets in the same workspace and will be available
|
|
## when this package is built. They are linked via target_link_libraries instead of CATKIN_DEPENDS
|
|
catkin_package(
|
|
INCLUDE_DIRS include
|
|
# LIBRARIES không cần vì đây là header-only library
|
|
# CATKIN_DEPENDS không cần vì dependencies không phải Catkin packages
|
|
)
|
|
endif()
|
|
|
|
# Thư viện header-only
|
|
add_library(robot_geometry_msgs INTERFACE)
|
|
|
|
# Include path tới thư mục chứa file header
|
|
target_include_directories(robot_geometry_msgs
|
|
INTERFACE
|
|
$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
|
|
$<INSTALL_INTERFACE:include>
|
|
)
|
|
|
|
# Liên kết với robot_std_msgs nếu bạn có file Header.h trong include/robot_std_msgs/
|
|
target_link_libraries(robot_geometry_msgs INTERFACE robot_std_msgs utils)
|
|
|
|
# Create alias for backward compatibility
|
|
add_library(geometry_msgs ALIAS robot_geometry_msgs)
|
|
|
|
# --- Cài đặt thư viện vào hệ thống khi chạy make install ---
|
|
# Export target trong mọi trường hợp để các target khác có thể export và phụ thuộc vào nó
|
|
install(TARGETS robot_geometry_msgs
|
|
EXPORT robot_geometry_msgs-targets
|
|
INCLUDES DESTINATION include # Cài đặt include
|
|
)
|
|
|
|
if(NOT BUILDING_WITH_CATKIN)
|
|
# Install headers for standalone mode
|
|
install(DIRECTORY include/
|
|
DESTINATION include
|
|
FILES_MATCHING PATTERN "*.h"
|
|
)
|
|
endif()
|
|
|
|
# --- Xuất export set robot_geometry_msgs-targets thành file CMake module ---
|
|
# --- Tạo file lib/cmake/robot_geometry_msgs/robot_geometry_msgs-targets.cmake ---
|
|
# --- File này chứa cấu hình giúp project khác có thể dùng ---
|
|
# --- Find_package(robot_geometry_msgs REQUIRED) ---
|
|
# --- Target_link_libraries(my_app PRIVATE robot_geometry_msgs::robot_geometry_msgs) ---
|
|
install(EXPORT robot_geometry_msgs-targets
|
|
FILE robot_geometry_msgs-targets.cmake
|
|
NAMESPACE robot_geometry_msgs::
|
|
DESTINATION lib/cmake/robot_geometry_msgs
|
|
)
|
|
|
|
add_executable(test_geometry test/main.cpp)
|
|
target_link_libraries(test_geometry PRIVATE robot_geometry_msgs)
|
|
|